mirror of
https://github.com/Start9Labs/start-os.git
synced 2026-03-30 12:11:56 +00:00
db0695126f
* store, properties, manifest * interfaces * init and backups * fix init and backups * file models * more versions * dependencies * config except dynamic types * clean up config * remove disabled from non-dynamic vaues * actions * standardize example code block formats * wip: actions refactor Co-authored-by: Jade <Blu-J@users.noreply.github.com> * commit types * fix types * update types * update action request type * update apis * add description to actionrequest * clean up imports * revert package json * chore: Remove the recursive to the index * chore: Remove the other thing I was testing * flatten action requests * update container runtime with new config paradigm * new actions strategy * seems to be working * misc backend fixes * fix fe bugs * only show breakages if breakages * only show success modal if result * don't panic on failed removal * hide config from actions page * polyfill autoconfig * use metadata strategy for actions instead of prev * misc fixes * chore: split the sdk into 2 libs (#2736) * follow sideload progress (#2718) * follow sideload progress * small bugfix * shareReplay with no refcount false * don't wrap sideload progress in RPCResult * dont present toast --------- Co-authored-by: Aiden McClelland <me@drbonez.dev> * chore: Add the initial of the creation of the two sdk * chore: Add in the baseDist * chore: Add in the baseDist * chore: Get the web and the runtime-container running * chore: Remove the empty file * chore: Fix it so the container-runtime works --------- Co-authored-by: Matt Hill <MattDHill@users.noreply.github.com> Co-authored-by: Aiden McClelland <me@drbonez.dev> * misc fixes * update todos * minor clean up * fix link script * update node version in CI test * fix node version syntax in ci build * wip: fixing callbacks * fix sdk makefile dependencies * add support for const outside of main * update apis * don't panic! * Chore: Capture weird case on rpc, and log that * fix procedure id issue * pass input value for dep auto config * handle disabled and warning for actions * chore: Fix for link not having node_modules * sdk fixes * fix build * fix build * fix build --------- Co-authored-by: Matt Hill <mattnine@protonmail.com> Co-authored-by: Jade <Blu-J@users.noreply.github.com> Co-authored-by: J H <dragondef@gmail.com> Co-authored-by: Jade <2364004+Blu-J@users.noreply.github.com> Co-authored-by: Matt Hill <MattDHill@users.noreply.github.com>
99 lines
2.0 KiB
JavaScript
99 lines
2.0 KiB
JavaScript
// #flavor:0.1.2-beta.1:0
|
|
// !( >=1:1 && <= 2:2)
|
|
|
|
VersionRange
|
|
= first:VersionRangeAtom rest:(_ ((Or / And) _)? VersionRangeAtom)*
|
|
|
|
Or = "||"
|
|
|
|
And = "&&"
|
|
|
|
VersionRangeAtom
|
|
= Parens
|
|
/ Anchor
|
|
/ Not
|
|
/ Any
|
|
/ None
|
|
|
|
Parens
|
|
= "(" _ expr:VersionRange _ ")" { return { type: "Parens", expr } }
|
|
|
|
Anchor
|
|
= operator:CmpOp? _ version:VersionSpec { return { type: "Anchor", operator, version } }
|
|
|
|
VersionSpec
|
|
= flavor:Flavor? upstream:Version downstream:( ":" Version )? { return { flavor: flavor || null, upstream, downstream: downstream ? downstream[1] : { number: [0], prerelease: [] } } }
|
|
|
|
Not = "!" _ value:VersionRangeAtom { return { type: "Not", value: value }}
|
|
|
|
Any = "*" { return { type: "Any" } }
|
|
|
|
None = "!" { return { type: "None" } }
|
|
|
|
CmpOp
|
|
= ">=" { return ">="; }
|
|
/ "<=" { return "<="; }
|
|
/ ">" { return ">"; }
|
|
/ "<" { return "<"; }
|
|
/ "=" { return "="; }
|
|
/ "!=" { return "!="; }
|
|
/ "^" { return "^"; }
|
|
/ "~" { return "~"; }
|
|
|
|
ExtendedVersion
|
|
= flavor:Flavor? upstream:Version ":" downstream:Version {
|
|
return { flavor: flavor || null, upstream, downstream }
|
|
}
|
|
|
|
EmVer
|
|
= major:Digit "." minor:Digit "." patch:Digit ("." revision:Digit)? {
|
|
return {
|
|
flavor: null,
|
|
upstream: {
|
|
number: [major, minor, patch],
|
|
prerelease: [],
|
|
},
|
|
downstream: {
|
|
number: [revision || 0],
|
|
prerelease: [],
|
|
},
|
|
}
|
|
}
|
|
|
|
Flavor
|
|
= "#" flavor:Lowercase ":" { return flavor }
|
|
|
|
Lowercase
|
|
= [a-z]+ { return text() }
|
|
|
|
String
|
|
= [a-zA-Z]+ { return text(); }
|
|
|
|
Version
|
|
= number:VersionNumber prerelease: PreRelease? {
|
|
return {
|
|
number,
|
|
prerelease: prerelease || []
|
|
};
|
|
}
|
|
|
|
PreRelease
|
|
= "-" first:PreReleaseSegment rest:("." PreReleaseSegment)* {
|
|
return [first].concat(rest.map(r => r[1]));
|
|
}
|
|
|
|
PreReleaseSegment
|
|
= "."? segment:(Digit / String) {
|
|
return segment;
|
|
}
|
|
|
|
VersionNumber
|
|
= first:Digit rest:("." Digit)* {
|
|
return [first].concat(rest.map(r => r[1]));
|
|
}
|
|
|
|
Digit
|
|
= [0-9]+ { return parseInt(text(), 10); }
|
|
|
|
_ "whitespace"
|
|
= [ \t\n\r]* |